FLIT  I  7-31-61 = section II
|Entrances and constant range test

prl,	clc
prw,	slr prx
	llr lwt
	slr t1
	trn srg
	llr adr
	lac
	add cdl
	trn irp
	lcc
	add cul
	trn irp

|Octal decimal constant print

tsu,	cla
	adtn sou,u
s,	call ppm
u,	adtn rdx,onp
dnp,	llr (add ddn
	tra .+2
onp,	llr (add odn
	slr np0
	load npg,trn npr
	cla
	add (-6+1
npr,	sto t3
	add np0
	sto np1
	sto np2
	load npt,llr nu
np3,	llcc t1
	trn np2
np1,	xx
np4,	com
	sto t1
	cstep npt,1
	load npg,opr
	tra np3
np2,	xx
	trn np4
	cla
	add t3
	add (1
npg,	xx
npt,	xx
	slr .+3
	type
np5,	add t3
	add (1
	trn npr
tcc,	cla
	tra tcn

NSTRUCTION REGISTER PRINT AND SYMBOLIC RANGE

IRP(	CLAD T1
	LLR (17777
	anl 20
	sto sym
	com
	trn va
	cyl
	trn va
	move t1, sym
	llr (tra ir3

ir1,	clad (-llr-syt
ir2,	slr evx
	load evy, tra ev7
	alo
	add (llr+2
	tra ev6

ir3,	add tt0
	trn vo2
vs1,	clad ev4
	trn onp
vs2,	add (-1
	sto vs3
	lcc
	add t1
	sto t1
vs3,	xx		|llr sym
	lcc
	print
	add t1
	trn tcc
	subr ppm, onp

va,	call ir1
	add ev4
	add (-1
	sto va3
	clad t1
	lcd
	com
	sto t1
va3,	xx		|llr sym
	lcc
	print
	type 001000+dc

srg,	clad t1
	sto sym
	add sll
	trn onp
	lcc
	add sul
	trn onp
	clad (-llr-ist
	subr ir2, vs1

vo2,	llr syt		|opr
	clad vo2
	tra vs2
|Table search routine : Evaluate symbol

evl,	slr evx
	lac
	acst 1,evy
	clac llr+1
	llrc -llr-syt
ev6,	add lim
ev0,	sto ev1
	slr tt0
	load t2,-400000
	load ev4,opr
ev1,	xx
	lac
	llr sym
	lpd
	trn ev2
	cry+com-opr
	trn ev3
	alr+com-opr
	add t2
	trn ev2
	slr t2
ev7,	move ev1,ev4
ev2,	cstep ev1,2
	adtn tt0,ev1
	clc
ev4,	xx
evx,	xx

ev3,	actn 1,ev2
	sto tt0
	adst ev1,ev5
ev5,	xx
evy,	xx

|Abval and print + or -

ppm,	slr pmx
	cla
	add t1
	trn pm
	llr (001101+lc
	tra pm1
pm,	com
	sto t1
	llr (011101+lc
pm1,	slr .+3
	type
pmx,	xx

|Carriage position control

tcs,	slr prx
tcn,	llr chn
tc0,	add wdc
	trn tc1
	amz
	trn tc8
	add (1
	sto wdc
	add (-4
	trn tc2
	clc
	add rop
	trn tc7
tc6,	add (101001+200202-1
	pnt
	pno
	add (1
	tra tc4
tc8,	type 000101+lc
	llr chn
	add (1
	tra tc9
tc2,	lac
	add (-ns2+nsd
	trn tcd
	add (-ns2
	trn tct
tc3,	add (-nsd
	alo
	tra tc0
tc1,	add rop
	trn tc7
tc9,	sto wdc
	lac
	add (-ns1+nsd
	trn tct
	tra tc3
tcd,	cla
	add (100101
	pnt
tct,	llr tai
	lcc
	trn tc5
	add (100101
	pno
	tra tc5
tc7,	add (101001
	pno
tc4,	sto wdc
tc5,	clc
	sto chn
	sto tai
	add rop
	llr .
	tra .+2
prx,	xx
	trn cob
	tra cor

|Depletion tables

np0,	+0
	100000
	10000
	1000
	100
	10
odn,	1
decimal
	100000
	10000
	1000
	100
	10
ddn,	1
octal

nu,	111110
	010101
	001111
	000111
	001011
	010011
	011011
	010111
	000011
	110110

|Print symbol routine

psy,	sto t2
	lac
	add (tra-llr+2
	sto psx
	llr (3
ps1,	slr t3
	llr t2
	lac
	llr (111111
	anl
	cyr
	sto t2
	slr ps2+2
ps2,	type
	add (-1
	add t3
	alr+com-opr
	trn ps1
psx,	xx

|Type subroutine

typ,	lac
	add (2
	sto ty1
	add (tra-llr+1
	sto scx
ty1,	xx
	lac
	trn ty0+1
	sto t
	cyl
	llr cas
	trn ty4
	lac
	trn ty0
	llr (111101
	tra .+2
ty5,	llr (111001
	com
	sto cas
	lac
	pno
	tra ty0
ty4,	lac
	trn ty5
ty0,	llr t
	clad (111111
	anl
	laz
	trn scx-1
	pno
	tra scn+1

|Color control

cor,	clc
	tra .+2
cob,	cla
	slr cox
	llr coi
	sto coi
	lpd+com-opr
	trn .+3
	add (010000
	pno
	add cox
	add (tra-llr+2
	sto cox
	cla
cox,	xx

|Ignore and illegal characters

e,	redd
	type 111010+uc
	add rop
	llr .
	trn cob
	type lc
	tra lsn

|Page position subroutine

igd,	addc -2
igc,	llrc tra lsn
scn,	slr scx
	addc 1
	add chn
	sto chn
	trn bs2
	alo
scx,	xx

|Error print routine

erp,	cla
	tra prr
dox,	alc
	add sai
	trn do1
	clc
	sto sai
	slr sad
do1,	llr tli
	lcc
	trn rst
tlt,	cla
	tra pfl
chk,	cla
	add (2
prr,	add (2
del,	add (2
pfl,	add (2
uds,	add (llr pdt
	sto pd1
	add (1
	sto pd2
	redd
pd1,	xx
	lac
	print
pd2,	xx
	lac
	print
	add rop
	trn rst
	llr (tra rnw
	clc
	tra tcs

pdt,	flex ind
	000010+022020
	flex fli
	100000
	flex xxx
	111010
	flex err
	110000+020200
	flex sum
	flex chk

start
a