FLIT  I  7-31-61 = section III
|Psuedo instruction list

pil,	-flex tab	tra tbl
	-flex oct	-tra-sro
	-flex dec	tra srd
	-flex sig	tra sns
	-flex uns	-tra-snu
	-flex ins	tra sip
	-flex con	tra spc
	-flex abs	tra sla
	-flex sym	tra sls
	-flex rea	tra red
	-flex cle	tra cl
	-flex wor	-tra-wds
	-flex add	-tra-ads
	-flex sur	tra sur
	-flex pri	tra pho
	-flex pun	-tra-pbb
	-flex sta	-tra-sta
	-flex res	-tra-res
	-flex inp	-tra-inp
	-flex beg	-tra-bgn
	-flex fee	-tra-in4
	-flex bre	-tra-brk
	-flex pro	-tra-pro

	npi=27
	pn1=13

|Search for psuedo instruction

spi,	load evx,tra erp
	load evy,tra sp1
	llr (-llr-pil-npi-npi+2
	clad (llr pil
	tra ev0
sp1,	sto dot
	acst -llr-pil+1,pin
	tra tsx

|Perform psuedo instruction

do,	move rb2,rbr
dou,	cal+com-opr
	slr wdc
	sto chn
dot,	xx
	lcc
	sto dot
	trn dou
maa,	clac -1
mab,	slr max
	acst llr ar1+1,ma1
	acst 1,ma2
	com
	add arc
	actn llr ar2,ma3
	clac 17777
ma1,	xx
	anl
	slr t
ma2,	xx
	anl
	lac
ma5,	sto tt1
	acst 1,ar2
	llcc t
	acst 1,ar1
	lcc
	add ar2
	trn erp
	cla
max,	xx

ma3,	llrc 20000
	clad pin
	actn -pn1-pn1+1,.+3
	llr lim
	lac+lro-opr
	addc -1
	slr t
	tra ma5

|Reset

res,	load lim,syt-nsm-nsm
	load syt-nsm-nsm,tra erp
	tra rsl

|Octal, decimal, etc.

sns,	add (1
snu,	sto sou
	tra rsl
srd,	add (1
sro,	sto rdx
	tra rsl
spc,	add ar1
	llr ar2
sc0,	slr cul
	sto cdl
	tra rsl
sip,	cal
	add (-20000+1
	tra sc0
sls,	add ar1
	llr ar2
sl0,	slr sul
	sto sll
	tra rsl
sla,	cal
	add (-20000+1
	tra sl0

|Define symbol

dfn,	slr dfy
	lac
	add (1
	sto dfx
	call evl
	tra df4
	acst slr-llr,df2
	add (-slr-syt+nsm+nsm
	trn df3
	lcc
	add wrd
	trn .+3
	clc
dfy,	xx
	add (1
	trn .-3
	tra df6
df4,	add lim
	add (-2
	sto lim
	add (1
	sto df1
	acst slr-sto+1,df2
	acst -2,df5
	llr sym
	lac
df1,	xx
	llr (tra erp
df5,	xx
df3,	llr wrd
df2,	xx
df6,	cla
dfx,	xx

|Read in symbol table

tbl,	call ski
	llr rb1
	lcc
	acst -llr+sto+1,tt1
	clad (llr buf
	tra tbi
tb2,	xx
	slr sym
tb3,	xx
	slr wrd
	lcc
	addc 20000
	trn tb0
	lac
	trn tb0
	add ar1
	trn tbj
	lcc
	add ar2
	trn tbj
tb0,	call dfn
	sto tli
tbj,	clad tb3
	add (1
tbi,	sto tb2
	acst 1,tb3
	add tt1
	trn tb2
tb5,	clad lst
	llr (77
	anl
	clc+lad-opr
	trn rb0
	subr rbk,rb0

|Read in binary tape

red,	load rbr,tra ch
	load sai,1
	sto chn
	subr ski,rb0

rd3,	slr .+2
	r3c
	xx
	tra rb3
rd4,	r3c
	tra rb3

|Surprise

sur,	call ski
	load su1,llr buf
	llr adr
sup,	lac
	sto lwt
	acst add,su2
ch,	lac
	adtn ar1,chy
	lcc
	adtn ar2,chy
	lcc
	adtn lim,chy-1
chx,	clad chn
	trn su1
	tra rd3
	sto tli
chy,	clad chn
	trn sui
	tra rd4
su1,	xx
	cla
su2,	xx
	sto tt1
	lpd
	trn sue
	amz
	trn sui
sue,	slr tt2
	cla
	call prl
	llr tt1
	slr lwt
	call prw
	llr tt2
	slr lwt
	load wdc,4
	redd
	call prw
sui,	step su1,1
	clad adr
	add (1
	alr
	slr adr
	add lst
	trn sup
	tra rb0

|Skip input and read binary block

	r3c
ski,	r3c+com-opr
	trn .-2
rbk,	slr rbx
rb0,	load rb1,sto buf
	r3c
	alr
	trn dox
	add (add
	trn dox
	slr adr
	slr tt0
	r3c
	sto lst
	lad
	sto cks
rbr,	xx
rb1,	xx
rb3,	add cks
	sto cks
	clad rb1
	add (1
	sto rb1
	add (-sto-buf-100
	trn .+2
	tra erp
	lac
	add (1
	alr
	add lst
	trn rbr
rb2,	r3c
	add cks
	com
	trn chk
	amz
	com
	trn chk
rbx,	xx

|Word and address search

ads,	add (17777
wds,	alo
	add arc
	trn erp
	add (-3
	trn .+4
	cla
	add ar4
	anl
	slr tt2
	cla
	add ar1
	ano
	slr t5
	call mab
	add (101001
	pno
	call asq
	slr lwt
	add (llr
	sto .+1
	xx
	slr t6
	clad tt2
	ano
	add t5
	lpd
	trn asi
	amz
	com
	trn asi
	call prl
	load wdc,4
	llr t6
	slr lwt
	subr prw,asi

|Print horizontal

pho,	add arc
	trn erp
	cla
	add (101001
	prt
	pno
	call asq
	acst llr,ph1
	clc
	add wdc
	trn ph2
ph1,	xx
	slr lwt
	cla
	subr prw,asi
ph2,	slr lwt
	subr prl,ph1

|Address sequencer

asq,	slr asx
	llr t
	slr adr
asr,	lcc
	add lim
	trn tlt
	lac
asx,	xx
asi,	cla
	add adr
	add (1
	sto adr
	alr+com-opr
	add ar2
	trn rst
	tra asr

|Clear routine

cl,	call asq
	sto cl3
	cla
	add ar3
cl3,	xx
	tra asi

|Begin

bgn,	add arc
	trn bg4
	llr ar1
bg5,	cla
	add (17777
	anl
	lac
	add (tra
	sto bgx
	load bdo,tra erp
	cla
	add arc
	add (-1
	trn bg1
	add (-1
	trn bg2
	llr ar3
	cla
	tra bg3
bg1,	cal
	tra bgx
bg2,	cal
bg3,	add ar2
bgx,	xx
bg4,	clad sai
	llr sad
	trn bg5
	tra erp

|Break point returns

ent,	slr lr
	lro
	tra en0
	slr lr
	llr (1
	tra en0
	slr lr
	llr (2
	tra en0
	slr lr
	llr (3
en0,	sto acc
	lac
	acst llr bop,en1
	acst brp-bop,en2
en1,	xx
	slr bdo
en2,	xx
	lac
	sto lwt
	acst tra+1,brt
	acst 1,brt+1
	cla
	sto chn
	sto wdc
	call prl
	load wdc,3
	slr pin
	addc 000110+022200+004000
	print
	add acc
	llr (tra en3
	tra en4
en3,	addc 100100+020200+004000
	print
	add lr
	llr (tra rst
en4,	sto t1
	slr prx
	tra onp

|Psuedo instruction proceed

pro,	cla
	add acc
	llr lr
bdo,	tra erp
brt,	xx
	xx

|Psuedo instruction break

brk,	add bpc
	trn set
	adddddd (-1
	sto bpc
	acst llr bop,br3
	acst brp-bop,br1
br1,	xx
	lac
	trn brk
	acst slr,br2
br3,	xx
br2,	xx
	clc
	tra brk
set,	add arc
	sto bpc
se0,	trn sex
	add (-1
	sto arc
	acst llr ar1,se1
	acst sto brp-llr-ar1,se5
	sto se6
	acst slr bop-sto-brp,se3
se1,	xx
	lac
	trn se7
	com
	add lim
	trn se7
	lac
se5,	xx
	sto se4
	acst llr,se2
se2,	xx
se3,	xx
	clad arc
	cyl+200
	lad
	add (tra ent
se4,	xx
se8,	clad arc
	tra se0
se7,	clc
	sto tli
se6,	xx
	tra se8
sex,	llr tli
	lac
	trn tlt
	tra rsl

|Punch input routine

inp,	llr (100
	p6s+lpd-opr
	add (-1
	alr+com-opr
	trn .-3
	llr 17760
in2,	lac
	add (1
	alr+com-opr
	add 17775
	trn in3
	lac
	add (add
	sto in1
	lac
	p7h
	p7h
	p7a
in1,	xx
	p7h
	p7h
	p7a
	tra in2
in3,	add (trn 17744
	p7h
	p7h
	p7a
in4,	llr (40
in5,	p6s+lpd-opr
	add (-1
	alr+com-opr
	trn .-3
	tra rsl

|Punch start block

sta,	llr (40
	p6s+lpd-opr
	add (-1
	alr+com-opr
	trn .-3
	add ar1
	add (add
	p7h
	p7h
	p7a
	llr (100
	tra in5


|Punch binary blocks

pbb,	add arc
	trn erp
	llr (tra rsl

p1r,	slr pby
	call maa
	load pbx, opr
	add t

pb0,	llr (77
	oro 60
	add tt1
	trn pb1		|if last block

pbz,	slr ar3
	p6s
	add t
	punch		|first addr
	lcc
	punch		|last addr
	lcc
	add t
	sto cks
	lad
	add (llr
	sto pbr
	lcc
	add (-llr
	sto tt0		|block end check

pbr,	xx		|llr ...
	lac
	add cks
	sto cks
	lac
	punch
	add pbr
	add one
	sto pbr
	add tt0
	trn pbr

	llr cks
	lcc
	punch
	p6s
	p6s 40
pbx,	xx
	llr ar3
	lac
	add one
	sto t
	tra pb0

pby,	xx

pb1,	move pby, pbx
	llr tt1		|absolute last addr
	tra pbz
|INDICATORS

adr,	+0
wrd,	+0
loc,	+0
lwt,	+0
lr,	+0
acc,	+0
pin,	+0
chc,	+0
arc,	+0
syc,	+0
wdc,	+0
chn,	+0
udf,	+0
ign,	+0
tai,	-0
let,	+0
psi,	+0
cas,	+0
coi,	+0
pun,	+0
gon,	-0
rop,	+0
lni,	+0
rdx,	-0
def,	+0
sou,	-0
tli,	+0
sym,	+0
onm,	+0
dnm,	+0
fld,	+0
ppr,	+0
syl,	+0
bpc,	-0
lst,	+0
cks,	+0
cdl,	20000
cul,	+0
sll,	+0
sul,	17777
lim,	syt-nsm-nsm
sai,	+0
sad=	+0
t,	+0
t1,	+0
t2,	+0
t3,	+0
t4,	+0
tt0,	+0
tt1,	+0
tt2,	+0
t5,	+0
t6,	+0

ar1,	0	ar2,	0
ar3,	0	ar4,	0
bop,	0	0	0	0
brp,	0	0	0	0

constants


17640|	buf,
start add rst